Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

GUI.GUITabControl


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
// ====================================================================
//	GUITabControl - This control has a number of tabs
/*=============================================================================
	In Game GUI Editor System V1.0
	2003 - Irrational Games, LLC.
	* Dan Kaplan
=============================================================================*/
#if !IG_GUI_LAYOUT
#error This code requires IG_GUI_LAYOUT to be defined due to extensive revisions of the origional code. [DKaplan]
#endif
/*===========================================================================*/

class GUITabControl extends GUIMultiComponent
        HideCategories(Menu,Object)
        ;

struct sTabButtonPair
{
    var() config Editinline GUIButton TabHeader "The header button for this tab";
    var() config Editinline GUIPanel TabPanel "The tab";
};

var(GUITabControl) EditInline Config array<sTabButtonPair> MyTabs "The tabs for this tab control";
var(GUITabControl) EditInline Config sTabButtonPair InitialTab "The initial tab for this tab control";
var(GUITabControl) EditInline EditConst sTabButtonPair ActiveTab "The active tab for this tab control";
var(GUITabControl) EditInline Config bool bAlwaysUseInitialTabWhenShown "If true, will set the active tab to the initial tab every time this is shown";

#if IG_TRIBES3 // dbeswick:
// return true to stop the switch
delegate function bool OnSwitch(GUIPanel Target);
#endif

function InitComponent(GUIComponent MyOwner)
{
    local int i;
	Super.InitComponent(MyOwner);

    for( i = 0; i < MyTabs.Length; i++ )
    {
        MyTabs[i].TabHeader.OnClick = TabHeaderClick;
        MyTabs[i].TabHeader.bNeverFocus = false;
        MyTabs[i].TabHeader.bMaintainFocus = true;
    }
    ActiveTab=InitialTab;
}

event Show()
{
    local int i;
    
    if( bAlwaysUseInitialTabWhenShown )
        ActiveTab=InitialTab;
    
    Super.Show();
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        MyTabs[i].TabHeader.Show();
    }

    ActiveTab.TabPanel.Show();
}

event Hide()
{
    local int i;
    
    Super.Hide();

    for( i = 0; i < MyTabs.Length; i++ )
    {
        MyTabs[i].TabHeader.Hide();
    }

    ActiveTab.TabPanel.Hide();
}

event Activate()
{
    local int i;
    
    Super.Activate();
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        MyTabs[i].TabHeader.Activate();
    }

    ActiveTab.TabHeader.Focus();
    ActiveTab.TabPanel.Activate();
}

event DeActivate()
{
    local int i;
    
    Super.DeActivate();

    for( i = 0; i < MyTabs.Length; i++ )
    {
        MyTabs[i].TabHeader.DeActivate();
    }

    ActiveTab.TabHeader.EnableComponent();
    ActiveTab.TabPanel.DeActivate();
}

#if IG_TRIBES3 // dbeswick:
function SetTabEnabled( GUIPanel Tab, bool bEnabled )
{
    local int i;
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        if( Tab == MyTabs[i].TabPanel )
        {
			if (bEnabled)
			{
				MyTabs[i].TabHeader.bCanBeShown = true;
				MyTabs[i].TabHeader.Show();
			}
			else
			{
				MyTabs[i].TabHeader.bCanBeShown = false;
				MyTabs[i].TabHeader.Hide();
			}

            return;
        }
    }
}
#endif

////////////////////////////////////////////////////////////////////////
//  Tab Header OnClick Delegate
////////////////////////////////////////////////////////////////////////
function TabHeaderClick(GUIComponent Sender)
{
	local sTabButtonPair tab;

	tab = GetTabByHeader(GUIButton(Sender));

#if IG_TRIBES3 // dbeswick:  Disallow the tab switch if OnSwitch() fails
	if (!OnSwitch(tab.TabPanel))
#endif
    OpenTab(GUIButton(Sender));
}

////////////////////////////////////////////////////////////////////////
//  Open Tab
////////////////////////////////////////////////////////////////////////
overloaded function OpenTab( int index )
{
    InternalOpenTabPair(GetTab(index));
}

overloaded function OpenTab( GUIPanel Tab )
{
    InternalOpenTabPair(GetTabByPanel(Tab));
}

overloaded function OpenTab( GUIButton Header )
{
    InternalOpenTabPair(GetTabByHeader(Header));
}

function InternalOpenTabPair( sTabButtonPair theTab )
{
    ActiveTab.TabHeader.EnableComponent();
    ActiveTab.TabPanel.DeActivate();
    ActiveTab.TabPanel.Hide();
    
    theTab.TabPanel.Show();
    theTab.TabPanel.Activate();
    theTab.TabHeader.Focus();

#if IG_TRIBES3 // dbeswick:
    theTab.TabHeader.MenuState = MSAT_Focused;
#endif

    ActiveTab=theTab;
}


//////////////////////////////////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////
// Dynamic Tab management
//////////////////////////////////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////

function sTabButtonPair CreateNewPair( string PanelClassName, string PanelName, string ButtonClassName, string ButtonName )
{
    local sTabButtonPair NewPair;
    
    NewPair.TabPanel = GUIPanel( AddComponent( PanelClassName, PanelName, true ) );
    NewPair.TabHeader = GUIButton( AddComponent( ButtonClassName, ButtonName, true ) );
    if( NewPair.TabHeader.Caption == "" )
        NewPair.TabHeader.SetCaption(ButtonName);
    
    return NewPair;
}

////////////////////////////////////////////////////////////////////////
//  Add Tab
////////////////////////////////////////////////////////////////////////
overloaded function AddTab( sTabButtonPair NewPair, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    AddTab( MyTabs.Length, NewPair, NewPanel, NewButton );
}

overloaded function AddTab( int index, sTabButtonPair NewPair, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    if( index < 0 )
        return;
    MyTabs[index]=NewPair;
    NewPair.TabHeader.OnClick = TabHeaderClick;
    NewPair.TabHeader.bNeverFocus = false;
    NewPair.TabHeader.bMaintainFocus = true;
    NewPair.TabHeader.Show();
    NewPair.TabHeader.Activate();
	NewPanel = NewPair.TabPanel;
	NewButton = NewPair.TabHeader;
}

overloaded function AddTab( string PanelClassName, string PanelName, string ButtonClassName, string ButtonName, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    AddTab( MyTabs.Length, PanelClassName, PanelName, ButtonClassName, ButtonName, NewPanel, NewButton );
}

overloaded function AddTab( int index, string PanelClassName, string PanelName, string ButtonClassName, string ButtonName, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    AddTab( index, CreateNewPair( PanelClassName, PanelName, ButtonClassName, ButtonName ), NewPanel, NewButton );
}

overloaded function AddTab( GUIPanel Panel, GUIButton Header, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    AddTab( MyTabs.Length, Panel, Header, NewPanel, NewButton );
}

overloaded function AddTab( int index, GUIPanel Panel, GUIButton Header, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    InternalAddTab( index, Panel, Header, NewPanel, NewButton );
}

function InternalAddTab( int index, GUIPanel Panel, GUIButton Header, optional out GUIPanel NewPanel, optional out GUIButton NewButton )
{
    local sTabButtonPair NewPair;
    
    if( index < 0 )
        return;

    NewPair.TabPanel = GUIPanel(AppendComponent(NewPanel));
    NewPair.TabHeader = GUIButton(AppendComponent(Header));

    AddTab( index, NewPair, NewPanel, NewButton );
}

////////////////////////////////////////////////////////////////////////
//  Remove Tab
////////////////////////////////////////////////////////////////////////
overloaded function RemoveTab( int index )
{
    RemoveComponent( MyTabs[index].TabHeader );
    RemoveComponent( MyTabs[index].TabPanel );
    MyTabs.Remove( index, 1 );
}

overloaded function RemoveTab( GUIPanel Panel )
{
    RemoveTab(GetTabIndexByPanel(Panel));
}

overloaded function RemoveTab( GUIButton Header )
{
    RemoveTab(GetTabIndexByHeader(Header));
}

overloaded function RemoveTab( String HeaderCaption )
{
	RemoveTab(GetTabIndexByHeaderCaption(HeaderCaption));
}

////////////////////////////////////////////////////////////////////////
//  Get Tab
////////////////////////////////////////////////////////////////////////
function sTabButtonPair GetTab( int index )
{
    return MyTabs[index];
}

function sTabButtonPair GetTabByPanel( GUIPanel Panel )
{
    return MyTabs[GetTabIndexByPanel(Panel)];
}

function sTabButtonPair GetTabByHeader( GUIButton Header )
{
    return MyTabs[GetTabIndexByHeader(Header)];
}

////////////////////////////////////////////////////////////////////////
//  Get Tab Index
////////////////////////////////////////////////////////////////////////
function int GetTabIndexByPanel( GUIPanel Panel )
{
    local int i;
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        if( Panel == MyTabs[i].TabPanel )
        {
            return i;
        }
    }
}

function int GetTabIndexByHeader( GUIButton Header )
{
    local int i;
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        if( Header == MyTabs[i].TabHeader )
        {
            return i;
        }
    }
}

function int GetTabIndexByHeaderCaption( String HeaderCaption )
{
    local int i;
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        if( MyTabs[i].TabHeader.Caption ~= HeaderCaption )
        {
            return i;
        }
    }

	return -1;
}

////////////////////////////////////////////////////////////////////////
//  Other Utilities
////////////////////////////////////////////////////////////////////////
function Clear()
{
    MyTabs.Remove( 0, MyTabs.Length );
}

function int Num()
{
    return MyTabs.Length;
}

function bool IsEmpty()
{
    return Num() == 0;
}

////////////////////////////////////////////////////////////////////////
//  Tab Alignment
//
//  Params:
//   AlignDirection - Direction to layout the buttons, defined in GUI.uc
//   ButtonsAlignedTopLeft - If true, buttons are aligned to the top or
//      the left of the panel; if false, to the bottom or the right
//   MaxButtonsPerRow - Maximum number of buttons to lay out in a single
//      row.  If there are more buttons than this, they will "wrap" to
//      additional rows as needed.
//   RowSize - Size of a row, in pixels.
//   RowSpacing - Number of pixels between rows of buttons.
//   ButtonSpacing - Number of pixels between buttons on the same row.
////////////////////////////////////////////////////////////////////////
function AlignTabs( eProgressDirection AlignDirection, bool ButtonsAlignedTopLeft, int MaxButtonsPerRow, float RowSize, float RowSpacing, float ButtonSpacing )
{
    local int i, NumRows;
    local float ButtonWidth, PanelWidth;
    local float ButtonHeight, PanelHeight;
    local float PanelTop;
    local float PanelLeft;
    
    if( MyTabs.Length == 0 )
        return;
    
    NumRows = ( (MyTabs.Length - 1) / MaxButtonsPerRow ) + 1;
    
    switch( AlignDirection )
    {
        case DIRECTION_LeftToRight:
        case DIRECTION_RightToLeft:
            PanelWidth=ClientBounds[2]-ClientBounds[0];
            PanelHeight=(ClientBounds[3]-ClientBounds[1]) - (float(NumRows) * RowSize);
            ButtonWidth=PanelWidth / float(MaxButtonsPerRow) - ButtonSpacing;
            ButtonHeight=RowSize-RowSpacing;

            PanelLeft=ClientBounds[0];
            if( ButtonsAlignedTopLeft )
                PanelTop=ClientBounds[1]+(ButtonHeight*NumRows);
            else
                PanelTop=ClientBounds[1];
            break;
        case DIRECTION_TopToBottom:
        case DIRECTION_BottomToTop:
            PanelWidth=ClientBounds[2]-ClientBounds[0] - (float(NumRows) * RowSize);
            PanelHeight=ClientBounds[3]-ClientBounds[1];
            ButtonWidth=RowSize-RowSpacing;
            ButtonHeight=PanelHeight / float(MaxButtonsPerRow) - ButtonSpacing;

            PanelTop=ClientBounds[1];
            if( ButtonsAlignedTopLeft )
                PanelLeft=ClientBounds[0]+(ButtonWidth*NumRows);
            else
                PanelLeft=ClientBounds[0];
            break;
    }
    
    for( i = 0; i < MyTabs.Length; i++ )
    {
        MyTabs[i].TabPanel.bScaled=false;
        MyTabs[i].TabPanel.WinLeft=PanelLeft;
        MyTabs[i].TabPanel.WinTop=PanelTop;
        MyTabs[i].TabPanel.WinWidth=PanelWidth;
        MyTabs[i].TabPanel.WinHeight=PanelHeight;

        MyTabs[i].TabHeader.bScaled=false;
        MyTabs[i].TabHeader.WinWidth=ButtonWidth;
        MyTabs[i].TabHeader.WinHeight=ButtonHeight;
        switch( AlignDirection )
        {
            case DIRECTION_LeftToRight:
                MyTabs[i].TabHeader.WinLeft=ClientBounds[0] + ((i%MaxButtonsPerRow)*(ButtonWidth+ButtonSpacing));
                if( ButtonsAlignedTopLeft )
                    MyTabs[i].TabHeader.WinTop=ClientBounds[1] + ((i/MaxButtonsPerRow)*(ButtonHeight+RowSpacing));
                else
                    MyTabs[i].TabHeader.WinTop=ClientBounds[3] - ((i/MaxButtonsPerRow+1)*(ButtonHeight+RowSpacing));
                break;
            case DIRECTION_RightToLeft:
                MyTabs[i].TabHeader.WinLeft=ClientBounds[0] + ((MaxButtonsPerRow - (i%MaxButtonsPerRow) - 1)*(ButtonWidth+ButtonSpacing));
                if( ButtonsAlignedTopLeft )
                    MyTabs[i].TabHeader.WinTop=ClientBounds[1] + ((i/MaxButtonsPerRow)*(ButtonHeight+RowSpacing));
                else
                    MyTabs[i].TabHeader.WinTop=ClientBounds[3] - ((i/MaxButtonsPerRow+1)*(ButtonHeight+RowSpacing));
                break;
            case DIRECTION_TopToBottom:
                MyTabs[i].TabHeader.WinTop=ClientBounds[1] + ((i%MaxButtonsPerRow)*(ButtonHeight+ButtonSpacing));
                if( ButtonsAlignedTopLeft )
                    MyTabs[i].TabHeader.WinLeft=ClientBounds[0] + ((i/MaxButtonsPerRow)*(ButtonWidth+RowSpacing));
                else
                    MyTabs[i].TabHeader.WinLeft=ClientBounds[2] - ((i/MaxButtonsPerRow+1)*(ButtonWidth+RowSpacing));
                break;
            case DIRECTION_BottomToTop:
                MyTabs[i].TabHeader.WinTop=ClientBounds[1] + ((MaxButtonsPerRow - (i%MaxButtonsPerRow) - 1)*(ButtonHeight+ButtonSpacing));
                if( ButtonsAlignedTopLeft )
                    MyTabs[i].TabHeader.WinLeft=ClientBounds[0] + ((i/MaxButtonsPerRow)*(ButtonWidth+RowSpacing));
                else
                    MyTabs[i].TabHeader.WinLeft=ClientBounds[2] - ((i/MaxButtonsPerRow+1)*(ButtonWidth+RowSpacing));
                break;
        }
    }
}

defaultproperties
{
    PropagateVisibility=false
    PropagateActivity=false
    PropagateState=false
	RenderWeight=0.2
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: ne 5.9.2004 16:02:10.000 - Creation time: st 23.5.2018 00:10:43.952 - Created with UnCodeX